home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 2010 April / PCWorld0410.iso / hity wydania / Ubuntu 9.10 PL / karmelkowy-koliberek-desktop-9.10-i386-PL.iso / casper / filesystem.squashfs / usr / bin / perlbug < prev    next >
Text File  |  2009-10-01  |  38KB  |  1,234 lines
  1. #!/usr/bin/perl
  2.     eval 'exec /usr/bin/perl -S $0 ${1+"$@"}'
  3.     if $running_under_some_shell;
  4.  
  5. my $config_tag1 = '5.10.0 - Thu Oct  1 22:38:45 UTC 2009';
  6.  
  7. my $patchlevel_date = 1197974828;
  8. my $patch_tags = '';
  9. my @patches = (
  10.     ''
  11. );
  12.  
  13. use Config;
  14. use File::Spec;        # keep perlbug Perl 5.005 compatible
  15. use Getopt::Std;
  16. use strict;
  17.  
  18. sub paraprint;
  19.  
  20. BEGIN {
  21.     eval "use Mail::Send;";
  22.     $::HaveSend = ($@ eq "");
  23.     eval "use Mail::Util;";
  24.     $::HaveUtil = ($@ eq "");
  25.     # use secure tempfiles wherever possible
  26.     eval "require File::Temp;";
  27.     $::HaveTemp = ($@ eq "");
  28.     eval { require Module::CoreList; };
  29.     $::HaveCoreList = ($@ eq "");
  30. };
  31.  
  32. my $Version = "1.36";
  33.  
  34. # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  35. # Changed in 1.07 to see more sendmail execs, and added pipe output.
  36. # Changed in 1.08 to use correct address for sendmail.
  37. # Changed in 1.09 to close the REP file before calling it up in the editor.
  38. #                 Also removed some old comments duplicated elsewhere.
  39. # Changed in 1.10 to run under VMS without Mail::Send; also fixed
  40. #                 temp filename generation.
  41. # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
  42. # Changed in 1.12 to check for editor errors, make save/send distinction
  43. #                 clearer and add $ENV{REPLYTO}.
  44. # Changed in 1.13 to hopefully make it more difficult to accidentally
  45. #                 send mail
  46. # Changed in 1.14 to make the prompts a little more clear on providing
  47. #                 helpful information. Also let file read fail gracefully.
  48. # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
  49. #                 Also report selected environment variables.
  50. # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
  51. # Changed in 1.17 Win32 support added.  GSAR 97-04-12
  52. # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
  53. # Changed in 1.19 '-ok' default not '-v'
  54. #                 add local patch information
  55. #                 warn on '-ok' if this is an old system; add '-okay'
  56. # Changed in 1.20 Added patchlevel.h reading and version/config checks
  57. # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
  58. # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
  59. # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
  60. # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
  61. # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
  62. # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
  63. # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
  64. # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
  65. # Changed in 1.29 Perlbug(tron): auto(-ok), short prompts RFOLEY 05-05-2000
  66. # Changed in 1.30 Added warnings on failure to open files MSTEVENS 13-07-2000
  67. # Changed in 1.31 Add checks on close().Fix my $var unless. TJENNESS 26-07-2000
  68. # Changed in 1.32 Use File::Spec->tmpdir TJENNESS 20-08-2000
  69. # Changed in 1.33 Don't require -t STDOUT for -ok.
  70. # Changed in 1.34 Added Message-Id RFOLEY 18-06-2002 
  71. # Changed in 1.35 Use File::Temp (patch from Solar Designer) NWCLARK 28-02-2004
  72. # Changed in 1.36 Initial Module::CoreList support Alexandr Ciornii 11-07-2007
  73.  
  74. # TODO: - Allow the user to re-name the file on mail failure, and
  75. #       make sure failure (transmission-wise) of Mail::Send is
  76. #       accounted for.
  77. #       - Test -b option
  78.  
  79. my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename, $messageid, $domain,
  80.     $subject, $from, $verbose, $ed, $outfile, $Is_MacOS, $category, $severity,
  81.     $fh, $me, $Is_MSWin32, $Is_Linux, $Is_VMS, $msg, $body, $andcc, %REP, $ok,
  82.     $Is_OpenBSD);
  83.  
  84. my $perl_version = $^V ? sprintf("%vd", $^V) : $];
  85.  
  86. my $config_tag2 = "$perl_version - $Config{cf_time}";
  87.  
  88. Init();
  89.  
  90. if ($::opt_h) { Help(); exit; }
  91. if ($::opt_d) { Dump(*STDOUT); exit; }
  92. if (!-t STDIN && !($ok and not $::opt_n)) {
  93.     paraprint <<EOF;
  94. Please use perlbug interactively. If you want to
  95. include a file, you can use the -f switch.
  96. EOF
  97.     die "\n";
  98. }
  99.  
  100. Query();
  101. Edit() unless $usefile || ($ok and not $::opt_n);
  102. NowWhat();
  103. Send();
  104.  
  105. exit;
  106.  
  107. sub ask_for_alternatives { # (category|severity)
  108.     my $name = shift;
  109.     my %alts = (
  110.     'category' => {
  111.         'default' => 'core',
  112.         'ok'      => 'install',
  113.         'opts'    => [qw(core docs install library utilities)], # patch, notabug
  114.     },
  115.     'severity' => {
  116.         'default' => 'low',
  117.         'ok'      => 'none',
  118.         'opts'    => [qw(critical high medium low wishlist none)], # zero
  119.     },
  120.     );
  121.     die "Invalid alternative($name) requested\n" unless grep(/^$name$/, keys %alts);
  122.     my $alt = "";
  123.     if ($ok) {
  124.     $alt = $alts{$name}{'ok'};
  125.     } else {
  126.      my @alts = @{$alts{$name}{'opts'}};
  127.     paraprint <<EOF;
  128. Please pick a \u$name from the following:
  129.  
  130.     @alts
  131.  
  132. EOF
  133.     my $err = 0;
  134.     do {
  135.         if ($err++ > 5) {
  136.         die "Invalid $name: aborting.\n";
  137.         }
  138.         print "Please enter a \u$name [$alts{$name}{'default'}]: ";
  139.         $alt = <>;
  140.         chomp $alt;
  141.         if ($alt =~ /^\s*$/) {
  142.         $alt = $alts{$name}{'default'};
  143.         }
  144.     } while !((($alt) = grep(/^$alt/i, @alts)));
  145.     }
  146.     lc $alt;
  147. }
  148.  
  149. sub Init {
  150.     # -------- Setup --------
  151.  
  152.     $Is_MSWin32 = $^O eq 'MSWin32';
  153.     $Is_VMS = $^O eq 'VMS';
  154.     $Is_Linux = lc($^O) eq 'linux';
  155.     $Is_OpenBSD = lc($^O) eq 'openbsd';
  156.     $Is_MacOS = $^O eq 'MacOS';
  157.  
  158.     @ARGV = split m/\s+/,
  159.         MacPerl::Ask('Provide command-line args here (-h for help):')
  160.         if $Is_MacOS && $MacPerl::Version =~ /App/;
  161.  
  162.     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
  163.  
  164.     # This comment is needed to notify metaconfig that we are
  165.     # using the $perladmin, $cf_by, and $cf_time definitions.
  166.  
  167.     # -------- Configuration ---------
  168.  
  169.     # perlbug address
  170.     $perlbug = 'perlbug@perl.org';
  171.  
  172.     # Test address
  173.     $testaddress = 'perlbug-test@perl.org';
  174.  
  175.     # Target address
  176.     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
  177.  
  178.     # Users address, used in message and in Reply-To header
  179.     $from = $::opt_r || "";
  180.  
  181.     # Include verbose configuration information
  182.     $verbose = $::opt_v || 0;
  183.  
  184.     # Subject of bug-report message
  185.     $subject = $::opt_s || "";
  186.  
  187.     # Send a file
  188.     $usefile = ($::opt_f || 0);
  189.  
  190.     # File to send as report
  191.     $file = $::opt_f || "";
  192.  
  193.     # File to output to
  194.     $outfile = $::opt_F || "";
  195.  
  196.     # Body of report
  197.     $body = $::opt_b || "";
  198.     
  199.     # Editor
  200.     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
  201.     || ($Is_VMS && "edit/tpu")
  202.     || ($Is_MSWin32 && "notepad")
  203.     || ($Is_MacOS && '')
  204.     || "vi";
  205.  
  206.     # Not OK - provide build failure template by finessing OK report
  207.     if ($::opt_n) {
  208.     if (substr($::opt_n, 0, 2) eq 'ok' )    {
  209.         $::opt_o = substr($::opt_n, 1);
  210.     } else {
  211.         Help();
  212.         exit();
  213.     }
  214.     }
  215.  
  216.     # OK - send "OK" report for build on this system
  217.     $ok = 0;
  218.     if ($::opt_o) {
  219.     if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
  220.         my $age = time - $patchlevel_date;
  221.         if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
  222.         my $date = localtime $patchlevel_date;
  223.         print <<"EOF";
  224. "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
  225. are more than 60 days old.  This Perl version was constructed on
  226. $date.  If you really want to report this, use
  227. "perlbug -okay" or "perlbug -nokay".
  228. EOF
  229.         exit();
  230.         }
  231.         # force these options
  232.         unless ($::opt_n) {
  233.         $::opt_S = 1; # don't prompt for send
  234.         $::opt_b = 1; # we have a body
  235.         $body = "Perl reported to build OK on this system.\n";
  236.         }
  237.         $::opt_C = 1; # don't send a copy to the local admin
  238.         $::opt_s = 1; # we have a subject line
  239.         $subject = ($::opt_n ? 'Not ' : '')
  240.             . "OK: perl $perl_version ${patch_tags}on"
  241.             ." $::Config{'archname'} $::Config{'osvers'} $subject";
  242.         $ok = 1;
  243.     } else {
  244.         Help();
  245.         exit();
  246.     }
  247.     }
  248.  
  249.     # Possible administrator addresses, in order of confidence
  250.     # (Note that cf_email is not mentioned to metaconfig, since
  251.     # we don't really want it. We'll just take it if we have to.)
  252.     #
  253.     # This has to be after the $ok stuff above because of the way
  254.     # that $::opt_C is forced.
  255.     $cc = $::opt_C ? "" : (
  256.     $::opt_c || $::Config{'perladmin'}
  257.     || $::Config{'cf_email'} || $::Config{'cf_by'}
  258.     );
  259.  
  260.     if ($::HaveUtil) {
  261.         $domain = Mail::Util::maildomain();
  262.     } elsif ($Is_MSWin32) {
  263.         $domain = $ENV{'USERDOMAIN'};
  264.     } else {
  265.         require Sys::Hostname;
  266.         $domain = Sys::Hostname::hostname();
  267.     }
  268.  
  269.     # Message-Id - rjsf
  270.     $messageid = "<$::Config{'version'}_${$}_".time."\@$domain>"; 
  271.  
  272.     # My username
  273.     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
  274.         : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
  275.         : $Is_MacOS ? $ENV{'USER'}
  276.         : eval { getpwuid($<) };    # May be missing
  277.  
  278.     $from = $::Config{'cf_email'}
  279.        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
  280.                ($me eq $::Config{'cf_by'});
  281. } # sub Init
  282.  
  283. sub Query {
  284.     # Explain what perlbug is
  285.     unless ($ok) {
  286.     paraprint <<EOF;
  287. This program provides an easy way to create a message reporting a bug
  288. in perl, and e-mail it to $address.  It is *NOT* intended for
  289. sending test messages or simply verifying that perl works, *NOR* is it
  290. intended for reporting bugs in third-party perl modules.  It is *ONLY*
  291. a means of reporting verifiable problems with the core perl distribution,
  292. and any solutions to such problems, to the people who maintain perl.
  293.  
  294. If you're just looking for help with perl, try posting to the Usenet
  295. newsgroup comp.lang.perl.misc.  If you're looking for help with using
  296. perl with CGI, try posting to comp.infosystems.www.programming.cgi.
  297. EOF
  298.     }
  299.  
  300.     # Prompt for subject of message, if needed
  301.     
  302.     if (TrivialSubject($subject)) {
  303.     $subject = '';
  304.     }
  305.  
  306.     unless ($subject) {
  307.     paraprint <<EOF;
  308. First of all, please provide a subject for the
  309. message. It should be a concise description of
  310. the bug or problem. "perl bug" or "perl problem"
  311. is not a concise description.
  312. EOF
  313.  
  314.     my $err = 0;
  315.     do {
  316.         print "Subject: ";
  317.         $subject = <>;
  318.         chomp $subject;
  319.         if ($err++ == 5) {
  320.         die "Aborting.\n";
  321.         }
  322.     } while (TrivialSubject($subject));
  323.     }
  324.  
  325.     # Prompt for return address, if needed
  326.     unless ($from) {
  327.     # Try and guess return address
  328.     my $guess;
  329.  
  330.     $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
  331.         if ($Is_MacOS) {
  332.             require Mac::InternetConfig;
  333.             $guess = $Mac::InternetConfig::InternetConfig{
  334.                 Mac::InternetConfig::kICEmail()
  335.             };
  336.         }
  337.  
  338.     unless ($guess) {
  339.         # move $domain to where we can use it elsewhere    
  340.         if ($domain) {
  341.         if ($Is_VMS && !$::Config{'d_socket'}) {
  342.             $guess = "$domain\:\:$me";
  343.         } else {
  344.             $guess = "$me\@$domain" if $domain;
  345.         }
  346.         }
  347.     }
  348.  
  349.     if ($guess) {
  350.         unless ($ok) {
  351.         paraprint <<EOF;
  352. Your e-mail address will be useful if you need to be contacted. If the
  353. default shown is not your full internet e-mail address, please correct it.
  354. EOF
  355.         }
  356.     } else {
  357.         paraprint <<EOF;
  358. So that you may be contacted if necessary, please enter
  359. your full internet e-mail address here.
  360. EOF
  361.     }
  362.  
  363.     if ($ok && $guess) {
  364.         # use it
  365.         $from = $guess;
  366.     } else {
  367.         # verify it
  368.         print "Your address [$guess]: ";
  369.         $from = <>;
  370.         chomp $from;
  371.         $from = $guess if $from eq '';
  372.     }
  373.     }
  374.  
  375.     if ($from eq $cc or $me eq $cc) {
  376.     # Try not to copy ourselves
  377.     $cc = "yourself";
  378.     }
  379.  
  380.     # Prompt for administrator address, unless an override was given
  381.     if( !$::opt_C and !$::opt_c ) {
  382.     paraprint <<EOF;
  383. A copy of this report can be sent to your local
  384. perl administrator. If the address is wrong, please
  385. correct it, or enter 'none' or 'yourself' to not send
  386. a copy.
  387. EOF
  388.     print "Local perl administrator [$cc]: ";
  389.     my $entry = scalar <>;
  390.     chomp $entry;
  391.  
  392.     if ($entry ne "") {
  393.         $cc = $entry;
  394.         $cc = '' if $me eq $cc;
  395.     }
  396.     }
  397.  
  398.     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
  399.     $andcc = " and $cc" if $cc;
  400.  
  401.     # Prompt for editor, if no override is given
  402. editor:
  403.     unless ($::opt_e || $::opt_f || $::opt_b) {
  404.     paraprint <<EOF;
  405. Now you need to supply the bug report. Try to make
  406. the report concise but descriptive. Include any
  407. relevant detail. If you are reporting something
  408. that does not work as you think it should, please
  409. try to include example of both the actual
  410. result, and what you expected.
  411.  
  412. Some information about your local
  413. perl configuration will automatically be included
  414. at the end of the report. If you are using any
  415. unusual version of perl, please try and confirm
  416. exactly which versions are relevant.
  417.  
  418. You will probably want to use an editor to enter
  419. the report. If "$ed" is the editor you want
  420. to use, then just press Enter, otherwise type in
  421. the name of the editor you would like to use.
  422.  
  423. If you would like to use a prepared file, type
  424. "file", and you will be asked for the filename.
  425. EOF
  426.     print "Editor [$ed]: ";
  427.     my $entry =scalar <>;
  428.     chomp $entry;
  429.  
  430.     $usefile = 0;
  431.     if ($entry eq "file") {
  432.         $usefile = 1;
  433.     } elsif ($entry ne "") {
  434.         $ed = $entry;
  435.     }
  436.     }
  437.     my $report_about_module = '';
  438.     if ($::HaveCoreList) {
  439.     paraprint <<EOF;
  440. Is your report about a Perl module? If yes, enter its name. If not, skip.
  441. EOF
  442.     print "Module []: ";
  443.     my $entry = scalar <>;
  444.     $entry =~ s/^\s+//s;
  445.     $entry =~ s/\s+$//s;
  446.     if ($entry ne q{}) {
  447.         $category ||= 'library';
  448.         $report_about_module = $entry;
  449.         my $first_release = Module::CoreList->first_release($entry);
  450.         unless ($first_release) {
  451.         paraprint <<EOF;
  452. Module $entry is not a core module. Please check that
  453. you entered its name correctly. If it is correct,
  454. abort this program, try searching for $entry on
  455. search.cpan.org, and report it there.
  456. EOF
  457.         }
  458.     }
  459.     }
  460.  
  461.     # Prompt for category of bug
  462.     $category ||= ask_for_alternatives('category');
  463.  
  464.     # Prompt for severity of bug
  465.     $severity ||= ask_for_alternatives('severity');
  466.  
  467.     # Generate scratch file to edit report in
  468.     $filename = filename();
  469.  
  470.     # Prompt for file to read report from, if needed
  471.     if ($usefile and !$file) {
  472. filename:
  473.     paraprint <<EOF;
  474. What is the name of the file that contains your report?
  475. EOF
  476.     print "Filename: ";
  477.     my $entry = scalar <>;
  478.     chomp $entry;
  479.  
  480.     if ($entry eq "") {
  481.         paraprint <<EOF;
  482. No filename? I'll let you go back and choose an editor again.
  483. EOF
  484.         goto editor;
  485.     }
  486.  
  487.     unless (-f $entry and -r $entry) {
  488.         paraprint <<EOF;
  489. I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
  490. the file? If you don't want to send a file, just enter a blank line and you
  491. can get back to the editor selection.
  492. EOF
  493.         goto filename;
  494.     }
  495.     $file = $entry;
  496.     }
  497.  
  498.     # Generate report
  499.     open(REP,">$filename") or die "Unable to create report file `$filename': $!\n";
  500.     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
  501.  
  502.     print REP <<EOF;
  503. This is a $reptype report for perl from $from,
  504. generated with the help of perlbug $Version running under perl $perl_version.
  505.  
  506. EOF
  507.  
  508.     if ($body) {
  509.     print REP $body;
  510.     } elsif ($usefile) {
  511.     open(F, "<$file")
  512.         or die "Unable to read report file from `$file': $!\n";
  513.     while (<F>) {
  514.         print REP $_
  515.     }
  516.     close(F) or die "Error closing `$file': $!";
  517.     } else {
  518.     print REP <<EOF;
  519.  
  520. -----------------------------------------------------------------
  521. [Please enter your report here]
  522.  
  523.  
  524.  
  525. [Please do not change anything below this line]
  526. -----------------------------------------------------------------
  527. EOF
  528.     }
  529.     Dump(*REP);
  530.     close(REP) or die "Error closing report file: $!";
  531.  
  532.     # read in the report template once so that
  533.     # we can track whether the user does any editing.
  534.     # yes, *all* whitespace is ignored.
  535.     open(REP, "<$filename") or die "Unable to open report file `$filename': $!\n";
  536.     while (<REP>) {
  537.     s/\s+//g;
  538.     $REP{$_}++;
  539.     }
  540.     close(REP) or die "Error closing report file `$filename': $!";
  541. } # sub Query
  542.  
  543. sub Dump {
  544.     local(*OUT) = @_;
  545.  
  546.     print OUT <<EFF;
  547. ---
  548. Flags:
  549.     category=$category
  550.     severity=$severity
  551. EFF
  552.     if ($::opt_A) {
  553.     print OUT <<EFF;
  554.     ack=no
  555. EFF
  556.     }
  557.     print OUT <<EFF;
  558. ---
  559. EFF
  560.     print OUT "This perlbug was built using Perl $config_tag1\n",
  561.         "It is being executed now by  Perl $config_tag2.\n\n"
  562.     if $config_tag2 ne $config_tag1;
  563.  
  564.     print OUT <<EOF;
  565. Site configuration information for perl $perl_version:
  566.  
  567. EOF
  568.     if ($::Config{cf_by} and $::Config{cf_time}) {
  569.     print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
  570.     }
  571.     print OUT Config::myconfig;
  572.  
  573.     if (@patches) {
  574.     print OUT join "\n    ", "Locally applied patches:", @patches;
  575.     print OUT "\n";
  576.     };
  577.  
  578.     print OUT <<EOF;
  579.  
  580. ---
  581. \@INC for perl $perl_version:
  582. EOF
  583.     for my $i (@INC) {
  584.     print OUT "    $i\n";
  585.     }
  586.  
  587.     print OUT <<EOF;
  588.  
  589. ---
  590. Environment for perl $perl_version:
  591. EOF
  592.     my @env =
  593.         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
  594.     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
  595.     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
  596.     my %env;
  597.     @env{@env} = @env;
  598.     for my $env (sort keys %env) {
  599.     print OUT "    $env",
  600.         exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
  601.         "\n";
  602.     }
  603.     if ($verbose) {
  604.     print OUT "\nComplete configuration data for perl $perl_version:\n\n";
  605.     my $value;
  606.     foreach (sort keys %::Config) {
  607.         $value = $::Config{$_};
  608.         $value =~ s/'/\\'/g;
  609.         print OUT "$_='$value'\n";
  610.     }
  611.     }
  612. } # sub Dump
  613.  
  614. sub Edit {
  615.     # Edit the report
  616.     if ($usefile || $body) {
  617.     paraprint <<EOF;
  618. Please make sure that the name of the editor you want to use is correct.
  619. EOF
  620.     print "Editor [$ed]: ";
  621.     my $entry =scalar <>;
  622.     chomp $entry;
  623.     $ed = $entry unless $entry eq '';
  624.     }
  625.  
  626. tryagain:
  627.     my $sts;
  628.     $sts = system("$ed $filename") unless $Is_MacOS;
  629.     if ($Is_MacOS) {
  630.         require ExtUtils::MakeMaker;
  631.         ExtUtils::MM_MacOS::launch_file($filename);
  632.         paraprint <<EOF;
  633. Press Enter when done.
  634. EOF
  635.         scalar <>;
  636.     }
  637.     if ($sts) {
  638.     paraprint <<EOF;
  639. The editor you chose (`$ed') could apparently not be run!
  640. Did you mistype the name of your editor? If so, please
  641. correct it here, otherwise just press Enter.
  642. EOF
  643.     print "Editor [$ed]: ";
  644.     my $entry =scalar <>;
  645.     chomp $entry;
  646.  
  647.     if ($entry ne "") {
  648.         $ed = $entry;
  649.         goto tryagain;
  650.     } else {
  651.         paraprint <<EOF;
  652. You may want to save your report to a file, so you can edit and mail it
  653. yourself.
  654. EOF
  655.     }
  656.     }
  657.  
  658.     return if ($ok and not $::opt_n) || $body;
  659.     # Check that we have a report that has some, eh, report in it.
  660.     my $unseen = 0;
  661.  
  662.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  663.     # a strange way to check whether any significant editing
  664.     # have been done: check whether any new non-empty lines
  665.     # have been added. Yes, the below code ignores *any* space
  666.     # in *any* line.
  667.     while (<REP>) {
  668.     s/\s+//g;
  669.     $unseen++ if $_ ne '' and not exists $REP{$_};
  670.     }
  671.  
  672.     while ($unseen == 0) {
  673.     paraprint <<EOF;
  674. I am sorry but it looks like you did not report anything.
  675. EOF
  676.     print "Action (Retry Edit/Cancel) ";
  677.     my ($action) = scalar(<>);
  678.     if ($action =~ /^[re]/i) { # <R>etry <E>dit
  679.         goto tryagain;
  680.     } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
  681.         Cancel();
  682.     }
  683.     }
  684. } # sub Edit
  685.  
  686. sub Cancel {
  687.     1 while unlink($filename);  # remove all versions under VMS
  688.     print "\nCancelling.\n";
  689.     exit(0);
  690. }
  691.  
  692. sub NowWhat {
  693.     # Report is done, prompt for further action
  694.     if( !$::opt_S ) {
  695.     while(1) {
  696.         paraprint <<EOF;
  697. Now that you have completed your report, would you like to send
  698. the message to $address$andcc, display the message on
  699. the screen, re-edit it, display/change the subject,
  700. or cancel without sending anything?
  701. You may also save the message as a file to mail at another time.
  702. EOF
  703.       retry:
  704.         print "Action (Send/Display/Edit/Subject/Save to File): ";
  705.         my $action = scalar <>;
  706.         chomp $action;
  707.  
  708.         if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
  709.         my $file_save = $outfile || "perlbug.rep";
  710.         print "\n\nName of file to save message in [$file_save]: ";
  711.         my $file = scalar <>;
  712.         chomp $file;
  713.         $file = $file_save if $file eq "";
  714.  
  715.         unless (open(FILE, ">$file")) {
  716.             print "\nError opening $file: $!\n\n";
  717.             goto retry;
  718.         }
  719.         open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
  720.         print FILE "To: $address\nSubject: $subject\n";
  721.         print FILE "Cc: $cc\n" if $cc;
  722.         print FILE "Reply-To: $from\n" if $from;
  723.         print FILE "Message-Id: $messageid\n" if $messageid;
  724.         print FILE "\n";
  725.         while (<REP>) { print FILE }
  726.         close(REP) or die "Error closing report file `$filename': $!";
  727.         close(FILE) or die "Error closing $file: $!";
  728.  
  729.         print "\nMessage saved in `$file'.\n";
  730.         exit;
  731.         } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
  732.         # Display the message
  733.         open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
  734.         while (<REP>) { print $_ }
  735.         close(REP) or die "Error closing report file `$filename': $!";
  736.         } elsif ($action =~ /^su/i) { # <Su>bject
  737.         print "Subject: $subject\n";
  738.         print "If the above subject is fine, just press Enter.\n";
  739.         print "If not, type in the new subject.\n";
  740.         print "Subject: ";
  741.         my $reply = scalar <STDIN>;
  742.         chomp $reply;
  743.         if ($reply ne '') {
  744.             unless (TrivialSubject($reply)) {
  745.             $subject = $reply;
  746.             print "Subject: $subject\n";
  747.             }
  748.         }
  749.         } elsif ($action =~ /^se/i) { # <S>end
  750.         # Send the message
  751.         print "Are you certain you want to send this message?\n"
  752.             . 'Please type "yes" if you are: ';
  753.         my $reply = scalar <STDIN>;
  754.         chomp $reply;
  755.         if ($reply eq "yes") {
  756.             last;
  757.         } else {
  758.             paraprint <<EOF;
  759. That wasn't a clear "yes", so I won't send your message. If you are sure
  760. your message should be sent, type in "yes" (without the quotes) at the
  761. confirmation prompt.
  762. EOF
  763.         }
  764.         } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
  765.         # edit the message
  766.         Edit();
  767.         } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
  768.         Cancel();
  769.         } elsif ($action =~ /^s/i) {
  770.         paraprint <<EOF;
  771. I'm sorry, but I didn't understand that. Please type "send" or "save".
  772. EOF
  773.         }
  774.     }
  775.     }
  776. } # sub NowWhat
  777.  
  778. sub TrivialSubject {
  779.     my $subject = shift;
  780.     if ($subject =~
  781.     /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
  782.     length($subject) < 4 ||
  783.     $subject !~ /\s/) {
  784.     print "\nThat doesn't look like a good subject.  Please be more verbose.\n\n";
  785.         return 1;
  786.     } else {
  787.     return 0;
  788.     }
  789. }
  790.  
  791. sub Send {
  792.     # Message has been accepted for transmission -- Send the message
  793.     if ($outfile) {
  794.     open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
  795.     goto sendout;
  796.     }
  797.  
  798.     # on linux certain mail implementations won't accept the subject
  799.     # as "~s subject" and thus the Subject header will be corrupted
  800.     # so don't use Mail::Send to be safe
  801.     if ($::HaveSend && !$Is_Linux && !$Is_OpenBSD) {
  802.     $msg = new Mail::Send Subject => $subject, To => $address;
  803.     $msg->cc($cc) if $cc;
  804.     $msg->add("Reply-To",$from) if $from;
  805.  
  806.     $fh = $msg->open;
  807.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  808.     while (<REP>) { print $fh $_ }
  809.     close(REP) or die "Error closing $filename: $!";
  810.     $fh->close;
  811.  
  812.     print "\nMessage sent.\n";
  813.     } elsif ($Is_VMS) {
  814.     if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
  815.          ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
  816.         my $prefix;
  817.         foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
  818.         $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
  819.         }
  820.         $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
  821.         $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
  822.     }
  823.     $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
  824.     my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
  825.     if ($sts) {
  826.         die <<EOF;
  827. Can't spawn off mail
  828.     (leaving bug report in $filename): $sts
  829. EOF
  830.     }
  831.     } else {
  832.     my $sendmail = "";
  833.     for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
  834.         $sendmail = $_, last if -e $_;
  835.     }
  836.     if ($^O eq 'os2' and $sendmail eq "") {
  837.         my $path = $ENV{PATH};
  838.         $path =~ s:\\:/: ;
  839.         my @path = split /$Config{'path_sep'}/, $path;
  840.         for (@path) {
  841.         $sendmail = "$_/sendmail", last if -e "$_/sendmail";
  842.         $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
  843.         }
  844.     }
  845.  
  846.     paraprint(<<"EOF"), die "\n" if $sendmail eq "";
  847. I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
  848. the perl package Mail::Send has not been installed, so I can't send your bug
  849. report. We apologize for the inconvenience.
  850.  
  851. So you may attempt to find some way of sending your message, it has
  852. been left in the file `$filename'.
  853. EOF
  854.     open(SENDMAIL, "|$sendmail -t -oi") || die "'|$sendmail -t -oi' failed: $!";
  855. sendout:
  856.     print SENDMAIL "To: $address\n";
  857.     print SENDMAIL "Subject: $subject\n";
  858.     print SENDMAIL "Cc: $cc\n" if $cc;
  859.     print SENDMAIL "Reply-To: $from\n" if $from;
  860.     print SENDMAIL "Message-Id: $messageid\n" if $messageid;
  861.     print SENDMAIL "\n\n";
  862.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  863.     while (<REP>) { print SENDMAIL $_ }
  864.     close(REP) or die "Error closing $filename: $!";
  865.  
  866.     if (close(SENDMAIL)) {
  867.         printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
  868.     } else {
  869.         warn "\nSendmail returned status '", $? >> 8, "'\n";
  870.     }
  871.     }
  872.     1 while unlink($filename);  # remove all versions under VMS
  873. } # sub Send
  874.  
  875. sub Help {
  876.     print <<EOF;
  877.  
  878. A program to help generate bug reports about perl5, and mail them.
  879. It is designed to be used interactively. Normally no arguments will
  880. be needed.
  881.  
  882. Usage:
  883. $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
  884.     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
  885. $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
  886.  
  887. Simplest usage:  run "$0", and follow the prompts.
  888.  
  889. Options:
  890.  
  891.   -v    Include Verbose configuration data in the report
  892.   -f    File containing the body of the report. Use this to
  893.         quickly send a prepared message.
  894.   -F    File to output the resulting mail message to, instead of mailing.
  895.   -S    Send without asking for confirmation.
  896.   -a    Address to send the report to. Defaults to `$address'.
  897.   -c    Address to send copy of report to. Defaults to `$cc'.
  898.   -C    Don't send copy to administrator.
  899.   -s    Subject to include with the message. You will be prompted
  900.         if you don't supply one on the command line.
  901.   -b    Body of the report. If not included on the command line, or
  902.         in a file with -f, you will get a chance to edit the message.
  903.   -r    Your return address. The program will ask you to confirm
  904.         this if you don't give it here.
  905.   -e    Editor to use.
  906.   -t    Test mode. The target address defaults to `$testaddress'.
  907.   -d    Data mode.  This prints out your configuration data, without mailing
  908.         anything. You can use this with -v to get more complete data.
  909.   -A    Don't send a bug received acknowledgement to the return address.
  910.   -ok   Report successful build on this system to perl porters
  911.         (use alone or with -v). Only use -ok if *everything* was ok:
  912.         if there were *any* problems at all, use -nok.
  913.   -okay As -ok but allow report from old builds.
  914.   -nok  Report unsuccessful build on this system to perl porters
  915.         (use alone or with -v). You must describe what went wrong
  916.         in the body of the report which you will be asked to edit.
  917.   -nokay As -nok but allow report from old builds.
  918.   -h    Print this help message.
  919.  
  920. EOF
  921. }
  922.  
  923. sub filename {
  924.     if ($::HaveTemp) {
  925.     # Good. Use a secure temp file
  926.     my ($fh, $filename) = File::Temp::tempfile(UNLINK => 1);
  927.     close($fh);
  928.     return $filename;
  929.     } else {
  930.     # Bah. Fall back to doing things less securely.
  931.     my $dir = File::Spec->tmpdir();
  932.     $filename = "bugrep0$$";
  933.     $filename++ while -e File::Spec->catfile($dir, $filename);
  934.     $filename = File::Spec->catfile($dir, $filename);
  935.     }
  936. }
  937.  
  938. sub paraprint {
  939.     my @paragraphs = split /\n{2,}/, "@_";
  940.     print "\n\n";
  941.     for (@paragraphs) {   # implicit local $_
  942.     s/(\S)\s*\n/$1 /g;
  943.     write;
  944.     print "\n";
  945.     }
  946. }
  947.  
  948. format STDOUT =
  949. ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
  950. $_
  951. .
  952.  
  953. __END__
  954.  
  955. =head1 NAME
  956.  
  957. perlbug - how to submit bug reports on Perl
  958.  
  959. =head1 SYNOPSIS
  960.  
  961. B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
  962. S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
  963. S<[ B<-r> I<returnaddress> ]>
  964. S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
  965. S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]>
  966.  
  967. B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
  968.  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
  969.  
  970. =head1 DESCRIPTION
  971.  
  972. A program to help generate bug reports about perl or the modules that
  973. come with it, and mail them.
  974.  
  975. If you have found a bug with a non-standard port (one that was not part
  976. of the I<standard distribution>), a binary distribution, or a
  977. non-standard module (such as Tk, CGI, etc), then please see the
  978. documentation that came with that distribution to determine the correct
  979. place to report bugs.
  980.  
  981. C<perlbug> is designed to be used interactively. Normally no arguments
  982. will be needed.  Simply run it, and follow the prompts.
  983.  
  984. If you are unable to run B<perlbug> (most likely because you don't have
  985. a working setup to send mail that perlbug recognizes), you may have to
  986. compose your own report, and email it to B<perlbug@perl.org>.  You might
  987. find the B<-d> option useful to get summary information in that case.
  988.  
  989. In any case, when reporting a bug, please make sure you have run through
  990. this checklist:
  991.  
  992. =over 4
  993.  
  994. =item What version of Perl you are running?
  995.  
  996. Type C<perl -v> at the command line to find out.
  997.  
  998. =item Are you running the latest released version of perl?
  999.  
  1000. Look at http://www.perl.com/ to find out.  If it is not the latest
  1001. released version, get that one and see whether your bug has been
  1002. fixed.  Note that bug reports about old versions of Perl, especially
  1003. those prior to the 5.0 release, are likely to fall upon deaf ears.
  1004. You are on your own if you continue to use perl1 .. perl4.
  1005.  
  1006. =item Are you sure what you have is a bug?
  1007.  
  1008. A significant number of the bug reports we get turn out to be documented
  1009. features in Perl.  Make sure the behavior you are witnessing doesn't fall
  1010. under that category, by glancing through the documentation that comes
  1011. with Perl (we'll admit this is no mean task, given the sheer volume of
  1012. it all, but at least have a look at the sections that I<seem> relevant).
  1013.  
  1014. Be aware of the familiar traps that perl programmers of various hues
  1015. fall into.  See L<perltrap>.
  1016.  
  1017. Check in L<perldiag> to see what any Perl error message(s) mean.
  1018. If message isn't in perldiag, it probably isn't generated by Perl.
  1019. Consult your operating system documentation instead.
  1020.  
  1021. If you are on a non-UNIX platform check also L<perlport>, as some
  1022. features may be unimplemented or work differently.
  1023.  
  1024. Try to study the problem under the Perl debugger, if necessary.
  1025. See L<perldebug>.
  1026.  
  1027. =item Do you have a proper test case?
  1028.  
  1029. The easier it is to reproduce your bug, the more likely it will be
  1030. fixed, because if no one can duplicate the problem, no one can fix it.
  1031. A good test case has most of these attributes: fewest possible number
  1032. of lines; few dependencies on external commands, modules, or
  1033. libraries; runs on most platforms unimpeded; and is self-documenting.
  1034.  
  1035. A good test case is almost always a good candidate to be on the perl
  1036. test suite.  If you have the time, consider making your test case so
  1037. that it will readily fit into the standard test suite.
  1038.  
  1039. Remember also to include the B<exact> error messages, if any.
  1040. "Perl complained something" is not an exact error message.
  1041.  
  1042. If you get a core dump (or equivalent), you may use a debugger
  1043. (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
  1044. report.  NOTE: unless your Perl has been compiled with debug info
  1045. (often B<-g>), the stack trace is likely to be somewhat hard to use
  1046. because it will most probably contain only the function names and not
  1047. their arguments.  If possible, recompile your Perl with debug info and
  1048. reproduce the dump and the stack trace.
  1049.  
  1050. =item Can you describe the bug in plain English?
  1051.  
  1052. The easier it is to understand a reproducible bug, the more likely it
  1053. will be fixed.  Anything you can provide by way of insight into the
  1054. problem helps a great deal.  In other words, try to analyze the
  1055. problem (to the extent you can) and report your discoveries.
  1056.  
  1057. =item Can you fix the bug yourself?
  1058.  
  1059. A bug report which I<includes a patch to fix it> will almost
  1060. definitely be fixed.  Use the C<diff> program to generate your patches
  1061. (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
  1062. package, so you should be able to get it from any of the GNU software
  1063. repositories).  If you do submit a patch, the cool-dude counter at
  1064. perlbug@perl.org will register you as a savior of the world.  Your
  1065. patch may be returned with requests for changes, or requests for more
  1066. detailed explanations about your fix.
  1067.  
  1068. Here are some clues for creating quality patches: Use the B<-c> or
  1069. B<-u> switches to the diff program (to create a so-called context or
  1070. unified diff).  Make sure the patch is not reversed (the first
  1071. argument to diff is typically the original file, the second argument
  1072. your changed file).  Make sure you test your patch by applying it with
  1073. the C<patch> program before you send it on its way.  Try to follow the
  1074. same style as the code you are trying to patch.  Make sure your patch
  1075. really does work (C<make test>, if the thing you're patching supports
  1076. it).
  1077.  
  1078. =item Can you use C<perlbug> to submit the report?
  1079.  
  1080. B<perlbug> will, amongst other things, ensure your report includes
  1081. crucial information about your version of perl.  If C<perlbug> is unable
  1082. to mail your report after you have typed it in, you may have to compose
  1083. the message yourself, add the output produced by C<perlbug -d> and email
  1084. it to B<perlbug@perl.org>.  If, for some reason, you cannot run
  1085. C<perlbug> at all on your system, be sure to include the entire output
  1086. produced by running C<perl -V> (note the uppercase V).
  1087.  
  1088. Whether you use C<perlbug> or send the email manually, please make
  1089. your Subject line informative.  "a bug" not informative.  Neither is
  1090. "perl crashes" nor "HELP!!!".  These don't help.
  1091. A compact description of what's wrong is fine.
  1092.  
  1093. =back
  1094.  
  1095. Having done your bit, please be prepared to wait, to be told the bug
  1096. is in your code, or even to get no reply at all.  The Perl maintainers
  1097. are busy folks, so if your problem is a small one or if it is difficult
  1098. to understand or already known, they may not respond with a personal reply.
  1099. If it is important to you that your bug be fixed, do monitor the
  1100. C<Changes> file in any development releases since the time you submitted
  1101. the bug, and encourage the maintainers with kind words (but never any
  1102. flames!).  Feel free to resend your bug report if the next released
  1103. version of perl comes out and your bug is still present.
  1104.  
  1105. =head1 OPTIONS
  1106.  
  1107. =over 8
  1108.  
  1109. =item B<-a>
  1110.  
  1111. Address to send the report to.  Defaults to B<perlbug@perl.org>.
  1112.  
  1113. =item B<-A>
  1114.  
  1115. Don't send a bug received acknowledgement to the reply address.
  1116. Generally it is only a sensible to use this option if you are a
  1117. perl maintainer actively watching perl porters for your message to
  1118. arrive.
  1119.  
  1120. =item B<-b>
  1121.  
  1122. Body of the report.  If not included on the command line, or
  1123. in a file with B<-f>, you will get a chance to edit the message.
  1124.  
  1125. =item B<-C>
  1126.  
  1127. Don't send copy to administrator.
  1128.  
  1129. =item B<-c>
  1130.  
  1131. Address to send copy of report to.  Defaults to the address of the
  1132. local perl administrator (recorded when perl was built).
  1133.  
  1134. =item B<-d>
  1135.  
  1136. Data mode (the default if you redirect or pipe output).  This prints out
  1137. your configuration data, without mailing anything.  You can use this
  1138. with B<-v> to get more complete data.
  1139.  
  1140. =item B<-e>
  1141.  
  1142. Editor to use.
  1143.  
  1144. =item B<-f>
  1145.  
  1146. File containing the body of the report.  Use this to quickly send a
  1147. prepared message.
  1148.  
  1149. =item B<-F>
  1150.  
  1151. File to output the results to instead of sending as an email. Useful
  1152. particularly when running perlbug on a machine with no direct internet
  1153. connection.
  1154.  
  1155. =item B<-h>
  1156.  
  1157. Prints a brief summary of the options.
  1158.  
  1159. =item B<-ok>
  1160.  
  1161. Report successful build on this system to perl porters. Forces B<-S>
  1162. and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
  1163. prompts for a return address if it cannot guess it (for use with
  1164. B<make>). Honors return address specified with B<-r>.  You can use this
  1165. with B<-v> to get more complete data.   Only makes a report if this
  1166. system is less than 60 days old.
  1167.  
  1168. =item B<-okay>
  1169.  
  1170. As B<-ok> except it will report on older systems.
  1171.  
  1172. =item B<-nok>
  1173.  
  1174. Report unsuccessful build on this system.  Forces B<-C>.  Forces and
  1175. supplies a value for B<-s>, then requires you to edit the report
  1176. and say what went wrong.  Alternatively, a prepared report may be
  1177. supplied using B<-f>.  Only prompts for a return address if it
  1178. cannot guess it (for use with B<make>). Honors return address
  1179. specified with B<-r>.  You can use this with B<-v> to get more
  1180. complete data.  Only makes a report if this system is less than 60
  1181. days old.
  1182.  
  1183. =item B<-nokay>
  1184.  
  1185. As B<-nok> except it will report on older systems.
  1186.  
  1187. =item B<-r>
  1188.  
  1189. Your return address.  The program will ask you to confirm its default
  1190. if you don't use this option.
  1191.  
  1192. =item B<-S>
  1193.  
  1194. Send without asking for confirmation.
  1195.  
  1196. =item B<-s>
  1197.  
  1198. Subject to include with the message.  You will be prompted if you don't
  1199. supply one on the command line.
  1200.  
  1201. =item B<-t>
  1202.  
  1203. Test mode.  The target address defaults to B<perlbug-test@perl.org>.
  1204.  
  1205. =item B<-v>
  1206.  
  1207. Include verbose configuration data in the report.
  1208.  
  1209. =back
  1210.  
  1211. =head1 AUTHORS
  1212.  
  1213. Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
  1214. by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>), Tom Christiansen
  1215. (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
  1216. Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
  1217. (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
  1218. Hugo van der Sanden (E<lt>hv@crypt.org<gt>),
  1219. Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
  1220. (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
  1221. and Richard Foley (E<lt>richard@rfi.netE<gt>).
  1222.  
  1223. =head1 SEE ALSO
  1224.  
  1225. perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
  1226. diff(1), patch(1), dbx(1), gdb(1)
  1227.  
  1228. =head1 BUGS
  1229.  
  1230. None known (guess what must have been used to report them?)
  1231.  
  1232. =cut
  1233.  
  1234.